Two question re SNMP and Centera...

Hi Dave

SNMP is configured typically as you specify when completing the CCRF Form. Customer Service will then use set snmp to specify the management station ip address, the community name and the heartbeat interval.

The default community name is public.

Below is the output from the online help of version 4.0

SNMP

The Simple Network Management Protocol is an Internet standard  protocol for managing devices on IP networks. SNMP compliant devices called  agents store data about the objects that can be monitored by a network  management system in Management Information Bases (MIB).

The Centera SNMP agent runs on all nodes with the management  role, responds to SNMP queries and pro-actively sends messages called traps to a  network management station. There are two traps defined in Centera: Heartbeat and Alarm.

A Compliance Edition Plus (CE+) model does not support SNMP  access on CentraStar version 2.3 and older.

MIB

The SNMP  implementation for Centera supports SNMP v2.0 and uses a proprietary EMC Centera MIBwithin the enterprises.emc.centera branch. The prefix in use for Centera in the  SNMP OID tree is enterprises.emc.centera.1.3.6.1.4.1.1139.5.  The MIB is located  on the Customer Tools CD and is installed in C:\Program  Files\EMC\Centera\4_0\SystemOperator\lib\centera.mib.

SNMP Queries

SNMP defines two  commands to retrieve information from an SNMP enabled device, in this case a  Centera:

• GET: Queries  the value of a single managed object. Centera replies with 'No such OID' message.

• GETNEXT:  Iterates through a tree of managed objects. Centera responds with an OID and a  value. This OID is the next OID for the NMS (Network Management Station) to  get.

SNMP Heartbeat Traps

The heartbeat trap  (enterprises.emc.centera.notificationTrap.trapNotification) is sent on a regular  basis. The primary function of the heartbeat trap is to report the actual state  of the system. The cause of the problem is not part of the message.

The heartbeat trap can send three types of messages to the  network management station, each describing a different level of problem  severity:

• Informational:  Displays the health of the Centera

• Warning:  Displays a non-critical error warning.

• Critical:  Displays a critical error message and that urgent action is  required.

The severity  level of the heartbeat trap is the worst actual system failure detected. Use the  heartbeat trap to quickly assess if there is a problem. The absence of the  heartbeat signal can also be an indicator of a problem.

SNMP Alarm Traps

The Alarm trap  (enterprises.emc.centera.notificationTrap.trapAlarmNotification) is sent when a  problem occurs on the Centera cluster. This trap is only sent when a problem  occurs. There are two error levels in this trap:

• Warning: A  non-critical error has occurred

• Critical: The  Centera cluster is in a critical state and urgent action is  required.

The severity level reported by the alarm trap equals the  most severe failure reported. The description field of the alarm trap contains a  short concise message stating the nature of the problem.

SNMP Limitations

Centera does not support SET commands; all configuration and  active management must be done via the CLI.

The Centera SNMP implementation uses a single trap for all  events, it does not have a separate OIB for each symptom code and does not send  resolution traps.

I hope this answers your questions. Wish you a nice day.

Holger

Hi Holger,

Thanks for taking the time to answer.

We've configured each our Centeras to send SNMP alerts to the IP address of one of our BMC Patrol servers at each site.

But, what I'm trying to do I script up our daily checks from a different server.

We've written our script and we've managed to be able to query all our other storage devices/platforms, but I'm having trouble querying the Centeras.

$/usr/sfw/bin/snmpwalk -v 1 -c public my-an01 system
Timeout: No Response from ddc-cen01-an01
$/usr/sfw/bin/snmpwalk -v 1 -c public my-an01 1.3.6.1.4.1.1139
Timeout: No Response from ddc-cen01-an01

I'm wondering if this is because only one target IP address for SNMP can be configured on the Centera, and thus SNMP gets from a different node fail?

Do the Centeras support SNMP v1?

Thanks again,

Dave.

Thanks Holger.

That's as I thought, that the Centera access nodes can't/don't respond to SNMP walks or SNMP gets.

I saw another post in this forum that used the CenteraViewer.jar constructs.

So, I borrowed the example, and a copy of my simple script is below for anyone else that might want to do something similar.

N.B. Other users may find that they need to logon using the normal CenteraViewer GUI and go to the CLI box and issue a "set cli" command to adjust (only) the number of scroll lines, so that the embedded calls inside the script below don't hang on a "more yes/no" prompt as the commands are run.

@echo off
setlocal enabledelayedexpansion

set z_path=%~dp0
set z_name=%~n0

set z_logs=!z_path!logs\

if not exist "!z_logs!" mkdir "!z_logs!"

set z_date=!date!

set z_date_dd=!z_date:~0,2!
set z_date_mm=!z_date:~3,2!
set z_date_yyyy=!z_date:~6,4!

set z_file_log=!z_logs!!z_name!-!z_date_yyyy!!z_date_mm!!z_date_dd!.log
if exist "!z_file_log!" del "!z_file_log!"

set z_file_tmp=!z_path!!z_name!.tmp
set z_file_txt=!z_path!!z_name!.txt

if exist "!z_file_tmp!" del "!z_file_tmp!"
if exist "!z_file_txt!" del "!z_file_txt!"

set z_jar_folder=D:\Program Files\EMC\Centera\4_0\SystemOperator\lib
if not exist "!z_jar_folder!" (
  call :log "Cannot locate folder `!z_jar_folder`..."
  goto :end
)

call :log ""
call :log "###########################################################"
call :log "Script started..."
call :log ""

:get-user
set z_user=
set /p z_user=!z_date! !time:~0,8!  _Please enter a username:
if /i "!z_user!"=="" goto :get-user
if /i "!z_user!"=="exit" goto :end
if /i "!z_user!"=="quit" goto :end

:get-pass
set z_pass=
set /p z_pass=!z_date! !time:~0,8!  _Please enter a password:
if /i "!z_pass!"=="" goto :get-pass
if /i "!z_pass!"=="exit" goto :end
if /i "!z_pass!"=="quit" goto :end

cls

call :log ""
call :log "Local Node:       !computername!"
call :log "Local Username:   !username!"
call :log "Source Node:      !clientname!"
call :log "Remote Username:  !z_user!"

    call :check-node "sitea-cen01-an01"
REM call :check-node "sitea-cen01-an02"
    call :check-node "siteb-cen02-an01"
REM call :check-node "siteb-cen02-an02"

call :log ""
call :log "###########################################################"
call :log "Script completed..."

:end
call :log ""
call :log "Script exiting..."

if exist "!z_file_tmp!" del "!z_file_tmp!"
if exist "!z_file_txt!" del "!z_file_txt!"

echo+
pause
exit /b

:log
echo !date! !time:~0,8!  %~1
echo !date! !time:~0,8!  %~1 >> "!z_file_log!"
goto :eof

:check-node
set z_node=%~1

call :log ""
call :log "###########################################################"
call :log "Checking node:    !z_node!"

for /f "tokens=1,2 skip=3" %%a in ('nslookup !z_node!') do (
  if "%%a"=="Address:" (
    set z_ip=%%b
  )
)

call :log "IP Address:       !z_ip!"

call :run-command "show pool capacity"           "ev-pool"
call :run-command "show replication detail"      "Replication Paused:"
call :run-command "show ip detail"               "Status:"
call :run-command "show node detail failure d"   "*"
call :run-command "show node detail failure v"   "*"

goto :eof

:run-command
set z_command=%~1

call :log ""
call :log "$ !z_command!"

if exist "!z_file_txt!" del "!z_file_txt!"
if exist "!z_file_tmp!" del "!z_file_tmp!"

echo !z_command! >> "!z_file_txt!"
echo quit        >> "!z_file_txt!"

set z_saved_cd=!cd!

cd "!z_jar_folder!"

java -cp CenteraViewer.jar com.filepool.remote.cli.CLI -u !z_user! -p !z_pass! -ip !z_ip! -script "!z_file_txt!" > "!z_file_tmp!"

set z_sts=!errorlevel!

cd "!z_saved_cd!"

REM pause

if "%~2"=="*" (
  for /f "tokens=* skip=9" %%a in ('type "!z_file_tmp!"') do (
    set z_line=%%a
    if "!z_line:~0,8!"=="Config# " set z_line=!z_line:~8,99!
    if not "!z_line!"=="" call :log "!z_line!"
  )
) else (
  for /f "tokens=* skip=2" %%a in ('find "%~2" "!z_file_tmp!"' ) do (
    call :log "%%a"
  )
)

goto :eof

Hi Dave

As I understood the implementation of SNMP in Centera I figured it would send out heartbeats and alerts. I am not aware that the Centera would respond to a direct request like you do. I thought it would just send the traps so that they could be displayed in a monitoring framework.

The Monitoring API though would allow writing a custom monitoring application and this one could also register for the events raised. We recently developed a simple function that reports pool capacity on different systems with customer name and used capacity so that this file can be uploaded to a billing application.

We could surely develop something for you too if the SNMP doesn't support what you are looking for.

Best regards and merry Christmas, Holger

Oh, and Merry Christmas and a Happy New Year to you too.